Jtdylktuy

I have been using this batch code: https://github.com/ITCMD/in2batch and it outputs something that looks like this:

(

echo gfgqebfwrwe

echo grgrgehrg4wer

echo htrehteertrehrt

+12,000 more lines of that

) >>outputfile.txt

(here is the actual file)
However the program just closes. It stops on line 10,692 with echo. There are no special characters on the line it stops on, or the line after. Does batch have a limit to how many lines of output can be inside a single ()?

Indeed, running unadjusted tempShare.bat led to cmd crash with application error and exception code 0xc00000fd which means Stack overflow (oddly enough - it stopped at different line if run repeatedly e.g. 10692/10711/10707 so I can't give any exact answer about count limit of lines in parentheses).

Fortunately, no error happens redirecting output from a for loop.

Hence, following slight changes to the original script led to desired effect. Adjusted script parses itself in a simple for /F loop and performs only echo commands between BEGIN CERTIFICATE and END CERTIFICATE inclusively (see lines 5..16):

@echo off

SETLOCAL enableextensions

if exist "7za.exe" goto :10897117303211127370517328436 

echo creating file . . .

set "_out="

(

for /f "usebackq tokens=*" %%G in ("%~f0") do (

  if "%%~G"=="echo -----BEGIN CERTIFICATE-----" set "_out=yes"

  if defined _out %%~G

  if "%%~G"=="echo -----END CERTIFICATE-----" set "_out="

)

)>temp.txt

certutil -v -decode "temp.txt" "7za.exe"

REM  >nul 

REM del /f /q "temp.txt"

goto :10897117303211127370517328436

(

echo -----BEGIN CERTIFICATE-----

echo TVqQAAMAAAAEAAAA//8AALgAAAAAAAAAQAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA

echo AAAAAAAAAAAAAAAA+AAAAA4fug4AtAnNIbgBTM0hVGhpcyBwcm9ncmFtIGNhbm5v

… truncated 12000+ lines of that …

echo AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA

echo AAAAAAAAAAAAAAAAAAAAAA==

echo -----END CERTIFICATE-----

)>temp.txt

certutil -v -decode "temp.txt" "7za.exe" >nul

del /f /q "temp.txt" 

:10897117303211127370517328436

pause

Output:

d:bat> erase 7za.exe 2>nul



d:bat> D:batSUtempShare.bat

creating file . . .

Input Length = 808252

Output Length = 587776

CertUtil: -decode command completed successfully.

Press any key to continue . . .



d:bat> 7za.exe -?



7-Zip (A) 9.20  Copyright (c) 1999-2010 Igor Pavlov  2010-11-18



Usage: 7za <command> [<switches>...] <archive_name> [<file_names>...]

       [<@listfiles...>]



… (truncated) …

The following tempShareExitLoop.bat does the same but stops reading itself after reaching the END CERTIFICATE line. Important: insert the :OutCertificate procedure somewhere (immediately) below some goto :eof in your code.

@echo off

SETLOCAL enableextensions

if exist "7za.exe" goto :10897117303211127370517328436 

echo creating file . . .

>temp.txt call :OutCertificate

certutil -v -decode "temp.txt" "7za.exe"

REM  >nul 

REM del /f /q "temp.txt"

goto :10897117303211127370517328436

(

echo -----BEGIN CERTIFICATE-----

echo TVqQAAMAAAAEAAAA//8AALgAAAAAAAAAQAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA

echo AAAAAAAAAAAAAAAA+AAAAA4fug4AtAnNIbgBTM0hVGhpcyBwcm9ncmFtIGNhbm5v

… truncated 12000+ lines of that …

echo AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA

echo AAAAAAAAAAAAAAAAAAAAAA==

echo -----END CERTIFICATE-----

)>temp.txt

certutil -v -decode "temp.txt" "7za.exe" >nul

del /f /q "temp.txt" 

:10897117303211127370517328436

pause

goto :eof 



:OutCertificate

set "_out="

for /f "usebackq tokens=*" %%G in ("%~f0") do (

  if "%%~G"=="echo -----BEGIN CERTIFICATE-----" set "_out=yes"

  if defined _out %%~G

  if "%%~G"=="echo -----END CERTIFICATE-----" goto :eof

)

goto :eof