Jtdylktuy

good afternoon,

I am working on an excel sheet where I have a table of data. This data represents several metrics that my department wants to keep track on. Whenever someone wants to populate the table with new data, the previous data in the cells are lost.

How can someone create a separate sheet where you can store all the values of that table automatically? I mean, when a change is done in one of the table cell, the new value to be automatically stored in another table that will keep all the values(old and new) of the cells? I tried the "track changes" but I'm not sure whether I like this way so much.

Does anyone know a more efficient way to do this? Through a macro for example?

Thank you!

(I'm on mobile so I can't provide a very fleshed out answer right now.)

I have written code to exactly this. My intent was to track all changes on a critical sheet edited by multiple users. If there was a dispute about where data came from, I could review the log. Here are VBA pieces that will come in handy.

Worksheet_Change event will fire every time the worksheet is changed.

If Not Intersect(Target, Range("A1:G12")) Is Nothing will tell you whether or not the cell(s) that changed are within some range you care about.

It's faster to store the values you want to log into an array and them set some range on your log sheet to be equal to that array as opposed to setting each cell on the log sheet individually.

Take a stab and see how far you get. I can be a little more verbose tomorrow.

Next Day Edit

Here's some code that will watch the range A1:G12 on whatever sheet has the code in it. If r is the row that was changed, then the code will copy everything from Ar:Gr into a sheet whose code name is shtLog. (Code name is the name shown in VBA, not the name on the tab you see in Excel.) This should get you moving in the right direction.

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim r As Integer

    Dim c As Integer

    Dim arr(1 To 1, 1 To 12)

    If Not Intersect(Target, Range("A1:G12")) Is Nothing Then

        r = Target.Row

        For c = 1 To 12

            arr(1, c) = Cells(r, c).Value

        Next

        With shtLog

            .Range(.Cells(.UsedRange.Rows.Count + 1, 1), .Cells(.UsedRange.Rows.Count + 1, 12)) = arr

        End With

    End If

End Sub

The built-in "Track Changes" functionality will likely be far more robust than any change tracking you attempt to implement with macros. Stick with that.

We (disclaimer, I'm the founder) built a audit trail system for Excel (like what Google Docs does, but for Excel). It doesn't require a shared workbook, and the audit trail is saved to a local SQL Database so it can be accessed from any workbook and saved as a separate sheet. Have a look: http://www.officeautomata.com

Building on Engineer Toast's answer, this logs the time and name of computer making the changes too. Note that the first row in shtLog must have content, otherwise the script will constantly overwrite row 2

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim r As Integer

    Dim c As Integer

    Dim arr(1 To 1, 1 To 26)



    ' Range to watch for changes

    If Not Intersect(Target, Range("A1:Z200")) Is Nothing Then



        ' Get row that has changed

        r = Target.Row

        For c = 1 To 26

            arr(1, c) = Cells(r, c).Value

        Next



          ' Count number of rows in table

         Dim rowCount As Integer

         rowCount = shtLog.UsedRange.Rows.Count



         ' Set row to use

         Dim rowToUse As Integer

         rowToUse = rowCount + 1



        ' Insert date at the start of the row

         shtLog.Cells(rowToUse, 1).Value = Format(Now(), "dd/mm/yyyy hh:nn AM/PM")



        ' Insert Computer nameto track whose made changes

        shtLog.Cells(rowToUse, 2).Value = Environ("USER")



        ' Insert the new values in to this row

        ' Note the cols have shift by +1 to allow for the date

         With shtLog

            .Range(.Cells(rowToUse, 3), .Cells(rowToUse, 28)) = arr

        End With

    End If

End Sub

With the Append feature of Sheetgo you can save keep a historic record of changing variables in Excel. More info in this blogpost: https://blog.sheetgo.com/how-to-solve-with-sheetgo/track-changes-in-excel-files/ (*disclaimer: I am a co-founder of Sheetgo).