Jtdylktuy

How can I archive emails into .pst files using a date range? I would like to create .pst file for each year.

I'm using MS Outlook 2003.

The only way I know is by using MS Outlook archiving tools. You can choose from/to (date) to archive and then name your pst files by name.

You can't chose from Jan. 1st 2009 to Jan. 1st 2010 but you can archive from now to Jan. 1st 2011. Then, Dec. 31 2010 to Jan. 1st 2010 and so on...

While this question is fairly old, I believe the techniques in Robert McMurry's macro would work for this, because it sounds like exactly what the original question is looking for.

In the interest of trying to prevent the worst losses of bit-rot, here's the relevant block of code. The actual article has much more detail on what it's doing and possible enhancements such as adding recursion; this appears to work on just a single folder ("Inbox") and can probably be used as a starting point.

Sub MoveOldEmails()



    ' Declare all variables.

    Dim objOutlook As Outlook.Application

    Dim objNamespace As Outlook.NameSpace

    Dim objSourceFolder As Outlook.MAPIFolder

    Dim objDestFolder As Outlook.MAPIFolder

    Dim objVariant As Variant

    Dim lngMovedMailItems As Long

    Dim intCount As Integer

    Dim intDateDiff As Integer

    Dim strDestFolder As String



    ' Create an object for the Outlook application.

    Set objOutlook = Application

    ' Retrieve an object for the MAPI namespace.

    Set objNamespace = objOutlook.GetNamespace("MAPI")

    ' Retrieve a folder object for the source folder.

    Set objSourceFolder = objNamespace.GetDefaultFolder(olFolderInbox)



    ' Loop through the items in the folder. NOTE: This has to

    ' be done backwards; if you process forwards you have to

    ' re-run the macro an inverese exponential number of times.

    For intCount = objSourceFolder.Items.Count To 1 Step -1

        ' Retrieve an object from the folder.

        Set objVariant = objSourceFolder.Items.Item(intCount)

        ' Allow the system to process. (Helps you to cancel the

        ' macro, or continue to use Outlook in the background.)

        DoEvents

        ' Filter objects for emails or meeting requests.

        If objVariant.Class = olMail Or objVariant.Class = olMeetingRequest Then

            ' This is optional, but it helps me to see in the

            ' debug window where the macro is currently at.

            Debug.Print objVariant.SentOn

            ' Calculate the difference in years between

            ' this year and the year of the mail object.

            intDateDiff = DateDiff("yyyy", objVariant.SentOn, Now)

            ' Only process the object if it isn't this year.

            If intDateDiff > 0 Then

                ' Calculate the name of the personal folder.

                strDestFolder = "Personal Folders (" & _

                    Year(objVariant.SentOn) & ")"

                ' Retrieve a folder object for the destination folder.

                Set objDestFolder = objNamespace.Folders(strDestFolder).Folders("Inbox")

                ' Move the object to the destination folder.

                objVariant.Move objDestFolder

                ' Just for curiousity, I like to see the number

                ' of items that were moved when the macro completes.

                lngMovedMailItems = lngMovedMailItems + 1

                ' Destroy the destination folder object.

                Set objDestFolder = Nothing

            End If

        End If

    Next



    ' Display the number of items that were moved.

    MsgBox "Moved " & lngMovedMailItems & " messages(s)."



End Sub